VBAのOn Error完全ガイド｜使い方・種類・注意点をわかりやすく解説

この記事を読んでわかること

VBAの「On Error」とは何なのかを知れる
「On Error」の種類や使い方を学べる
「On Error」を扱う際の注意点がわかる

※わかりやすさを重視しております。厳密には解釈が異なる場合がありますことをご了承ください。

－著者情報－
名前：Utatane
VBA（マクロ）歴：3年
Excel使用歴：15年以上
ひとこと：初心者だった当時に戻った気持ちになって解説いたします

スポンサードリンク

VBAのOn Errorとは？
1. なぜOn Errorが必要なのか
2. 日常に例えて解説
On Errorの種類と使い方
エラー内容を取得
より実践的な応用例
注意すべきポイント
最後に

VBAのOn Errorとは？

「On Error」は、マクロ実行中にエラーが発生したとき、動作を指定することができる命令です。

なぜそんなことが必要になるのでしょうか？

なぜOn Errorが必要なのか

「On Error」が必要な理由はただ一つで、「止まらないマクロ」を実現するためです。
「On Error」を使用しないと、エラーが発生した時点でマクロが強制終了してしまいます。

「On Error」を使用することで、エラーが発生しても無視して進行することもできるため、最後まで処理を実行することができます。

なかなかピンと来ないと思いますので、もう少しわかりやすい例で解説いたします。

日常に例えて解説

１～５までの５つの処理をさせたくて、「１・２・３・４・５」とプログラムを書いたとします。
このとき、２つめでエラーが発生してしまうと、２以降のプログラムは処理されず、異常終了されてしまいます。
わかりやすく例を挙げてみましょう。

朝起きてからのルーティンを決めたとします。

顔を洗う
トイレに行く
朝ごはんを食べる
歯を磨く
家を出る

２つ目の「トイレに行く」で誰かがトイレに入っていたら、トイレに行けずエラーになります。

プログラミングの世界では、ここで止まってしまって家を出ることができません。
「3.ごはんが炊けてなかったら」「4.歯ブラシが無かったら」という場合も同じです。

しかし「On Error」を使うことで、何らかのエラーが発生しても処理を止めず、最後まで完了させることができるのです。
上の例では、「誰かがトイレに入っていたらトイレに行かない」、「ごはんが炊けてなかったらパンを食べる」など、スキップしたり、別の処理をさせたりできます。

If文のエラー版といったところでしょうか…。

＜「On Error」を使わなかった場合＞

顔を洗う：正常終了
トイレに行く：エラー発生　できない
朝ごはんを食べる：できない
歯を磨く：できない
家を出る：できない

＜「On Error」を使った場合＞

顔を洗う：正常終了
トイレに行く：エラー発生（スキップ）
朝ごはんを食べる：正常終了
歯を磨く：正常終了
家を出る：正常終了　いってきます！

スポンサードリンク

On Errorの種類と使い方

「On Error」には大きく分けて３つの種類があります。

スキップ
ジャンプ
On Errorの解除

１つ１つ解説していきましょう。

スキップ

On Error Resume Next

エラーが発生した処理をスキップしてプログラムを進める記述です。
まずは「On Error」を使わない例から紹介いたします。
下記のVBAコードを見てください。

Sub スキップ()
    Worksheets("存在しないシート").Select ' エラー発生
    Debug.Print "Utatane" ' 実行されない
End Sub

前提知識｛マクロの基礎・作り方から実行まで｝
前提知識｛「Debug.Print」で値を表示させる方法｝

2行目で存在しないシートを選択した例です。
シートが存在しなかったため、エラーが発生し、3行目の処理は実行されません。

では次に、「On Error」のスキップを使ってエラーが出た処理を無視した例です。

Sub スキップ()
    On Error Resume Next ' エラーが発生してもスキップ
    Worksheets("存在しないシート").Select ' エラー発生 → スキップされる
    Debug.Print "Utatane" ' 実行される
End Sub

2行目で「On Error」のスキップを記述しているため、その後の処理でエラーが出た場合はスキップされます。
結果、3行目の処理でエラーが出ますがスキップされ、4行目の処理が実行されます。

さきほどは実行できなかった「Utatane」の表示が実行できました。
これが「On Error」の効果です。

ジャンプ

On Error GoTo ジャンプする場所

ジャンプする場所:

エラーが発生した場合に別の場所にジャンプすることができます。
下記VBAコードはその使用例です。

Sub ジャンプ()
    On Error GoTo エラー ' エラーが発生したら、「エラー」へジャンプ
    Worksheets("存在しないシート").Select ' エラー発生 → 「エラー」へジャンプ
    Debug.Print "完了しました" ' 実行されない

エラー:
    Debug.Print "エラーによりシートが開けませんでした。" ' これが実行される
End Sub

2行目がジャンプの記述です。
エラーが発生した場合にジャンプする場所を指定します。

3行目でエラーが発生したため、指定の場所にジャンプします。
（エラーが発生しなければ「完了しました」が表示される）

6行目がジャンプしてくる場所です。
ここにエラーが発生した場合の処理を記述します。
結果、「エラーによりシートが開けませんでした。」が表示されるわけです。

このように、エラーが発生した場合としなかった場合とで違う処理をさせることができます。

On Errorの解除

On Error GoTo 0

一番重要なところです。
「On Error」を使うと、その後ずっとエラースキップなどが適用されます。
そこで「On Error」を解除することが必要です。

スキップと併せて解除を用いた例です。

Sub スキップと解除()
    On Error Resume Next ' エラーが発生してもスキップ
    Worksheets("存在しないシート").Select ' エラー発生 → スキップされる
    Debug.Print "Utatane1" ' 実行される

    On Error GoTo 0 ' On Errorの解除
    Worksheets("存在しないシート").Select ' エラー発生 → 解除後なのでスキップされない
    Debug.Print "Utatane2" ' 実行されない
End Sub

6行目で「On Error」を解除したため、
7行目のエラースキップは行われず、処理が中断されます。

予期せぬエラーがスキップされてしまう恐れがある場合は、必ず「On Error」を解除しておきましょう。

スポンサードリンク

エラー内容を取得

「Errオブジェクト」を利用することで、エラー内容を取得することも可能です。
まずはエラーが発生していない場合のエラー内容を取得してみましょう。

Sub エラー内容を表示()
    Debug.Print "エラー番号：" & Err.Number & vbCrLf & "内容：" & Err.Description & vbCrLf & "発生元：" & Err.Source
End Sub

Err.Number：エラー番号
Err.Description：エラー内容の説明
Err.Source：エラーの発生元
Err.Clear：エラー情報の初期化

エラー番号が「0」と表示されました。
これがエラーなしの状態です。

次にエラーが発生した場合の内容を取得してみましょう。

Sub エラー内容を表示()
    On Error Resume Next ' エラーが発生してもスキップ
    Worksheets("存在しないシート").Select ' エラー発生 → スキップされる
    If Err.Number <> 0 Then ' エラーが発生している場合の処理
        Debug.Print "エラー番号：" & Err.Number & vbCrLf & "内容：" & Err.Description & vbCrLf & "発生元：" & Err.Source
        Err.Clear ' エラー情報の初期化
    End If
    On Error GoTo 0 ' On Errorの解除
End Sub

前提知識｛条件分岐（If）｝

Ifを使って、エラーなし（エラー番号が0）以外ならエラーの内容を取得するようにしています。

エラー内容が取得できました。

「これを見ても何のエラーかわからないよ…」と思うかもしれませんが、私たちが見るのではなく、プログラムに判断させます。

例えばエラー番号によって、違うところにジャンプさせたりスキップさせたりできるため、さらに幅広いエラー処理をさせることができるわけです。

スポンサードリンク

より実践的な応用例

下記VBAコードは、ファイルを開く際に「On Error」を使ってファイルが存在するかを確認した例です。

Sub ファイルが存在するかを確認してから開く()
    Dim filePath As String
    filePath = "C:\Utatane\test.xlsx" ' ファイルパスの代入
    
    On Error Resume Next ' エラーのスキップ
    Workbooks.Open Filename:=filePath ' ファイルを開く
    If Err.Number <> 0 Then ' エラーが発生した場合の処理
        Debug.Print "ファイルを開くことができませんでした: " & vbCrLf & Err.Description ' エラー内容の表示
        Err.Clear ' エラー情報の初期化
    End If
    On Error GoTo 0 ' On Errorの解除
End Sub