【Excelマクロ】VBAでMatch関数を使う方法｜エラー対策と複数処理の解説付き

▼ExcelのMATCH関数
=MATCH(検索値, 検索範囲, [照合の種類])

▼VBAのMatch関数
Application.Match(検索値, 検索範囲, [照合の種類])

▼VBAのMatch関数（使用例）
Application.Match("Utatane", Range("A1:A5"), 0)

Sub マッチ()
    Dim idx As Variant
    idx = Application.Match("A3", Range("A1:A5"), 0)
    
    Debug.Print "A3は " & idx & " 行目にあります。"
End Sub

Sub マッチ()
    Dim idx As Variant
    idx = Application.Match("B3", Range("A1:A5"), 0)
    
    Debug.Print idx
End Sub

Sub エラー回避マッチ()
    Dim idx As Variant
    idx = Application.Match("A3", Range("A1:A5"), 0)
    
    If IsError(idx) Then
        Debug.Print "A3は見つかりませんでした。"
    Else
        Debug.Print "A3は " & idx & " 行目にあります。"
    End If
End Sub

Sub 複数マッチ()
    Dim cell As Range
    Dim matchRange As Range
    Dim keyword As String
    Dim result As String

    keyword = "A3"
    Set matchRange = Range("A1:A5")
    result = ""

    For Each cell In matchRange
        If cell.Value = keyword Then
            result = result & cell.Address & vbCrLf
        End If
    Next

    If result = "" Then
        Debug.Print "A3は見つかりませんでした。"
    Else
        Debug.Print "A3が入力されたセル：" & vbCrLf & result
    End If
End Sub

Sub どちらかマッチ()
    Dim matchRange As Range
    Dim cell As Range
    Dim result As String
    Dim keyword1 As String, keyword2 As String

    keyword1 = "A2"
    keyword2 = "A3"
    Set matchRange = Range("A1:A5") ' 検索対象範囲
    result = ""

    For Each cell In matchRange
        If cell.Value = keyword1 Or cell.Value = keyword2 Then
            result = result & cell.Address(False, False) & " (" & cell.Value & ")" & vbCrLf
        End If
    Next

    If result = "" Then
        Debug.Print "A2 or A3は見つかりませんでした"
    Else
        Debug.Print "A2 or A3が入力されたセル：" & vbCrLf & result
    End If
End Sub

Sub 名前を検索して部署名を表示()
    Dim nameList As Range
    Dim deptList As Range
    Dim nameToFind As String
    Dim idx As Variant
    Dim department As Variant
    
    Set nameList = Range("A2:A5")    ' 名前列を取得
    Set deptList = Range("B2:B5")    ' 部署列を取得
    nameToFind = "田中"
    
    idx = Application.Match(nameToFind, nameList, 0) ' 名前を検索
    
    If IsError(idx) Then
        Debug.Print nameToFind & " さんは見つかりませんでした。"
    Else
        department = Application.Index(deptList, idx) ' 名前に対応した部署を取得
        Debug.Print nameToFind & " さんの部署は " & department & " です。"
    End If
End Sub

Sub プロパティを取得できませんを再現()
    Dim idx As Variant
    idx = Application.WorksheetFunction.Match("B3", Range("A1:A5"), 0)
    
    Debug.Print idx
End Sub

Sub マッチ()
    Dim idx As Variant
    On Error GoTo ErrorHandler
    idx = Application.WorksheetFunction.Match("B3", Range("A1:A5"), 0)
    Debug.Print "B3は " & idx & " 行目にあります。"
    Exit Sub
ErrorHandler:
    Debug.Print "見つかりませんでした。"
End Sub